Document Attachment with Item Journal Table in Business Central

-

Business Central already provides the Document Attachment framework, but sometimes you need to extend it to work with additional tables.
In this blog, I’ll show you how I extended the Document Attachment functionality to support the Item Journal Line table.

By the end, you’ll be able to attach documents (like invoices, PDFs, or scanned files) directly to item journal lines and view them from the journal page.

Step 1: Extend the Document Type

First, extend the Document Type in the Document Attachment table to include a new option for Item Journal.
This makes it possible to tag an attachment specifically for an item journal line.

enumextension 50500 "Attachment Dc" extends "Attachment Document Type"
{

    value(50500; "Item Journal")
    {
        Caption = 'Item Journal';
    }
}


Step 2: Add Template Name and Batch Name Fields

The standard Document Attachment table doesn’t store the Template Name and Batch Name fields that are needed to uniquely identify an Item Journal Line.

So we extend the table with two new fields:

tableextension 50501 DocumentAttachment extends "Document Attachment"
{
    fields
    {
        field(50500; "Template Name"; Code[20])
        {
            Caption = 'Template Name';
            DataClassification = ToBeClassified;
        }
        field(50501; "Batch Name"; Code[20])
        {
            Caption = 'Batch Name';
            DataClassification = ToBeClassified;
        }
    }
}


Step 3: Add a FactBox on the Item Journal Page

To make attachments visible from the journal, we add a FactBox on the Item Journal page.

This FactBox points to the Document Attachment List FactBox and links the relevant keys (Table ID, Template Name, Batch Name, and Line No.):

pageextension 50502 "Item Journal" extends "Item Journal"
{

    layout
    {
        addafter(JournalErrorsFactBox)
        {
            part("Attached Documents List"; "Doc. Attachment List Factbox")
            {
                ApplicationArea = All;
                Caption = 'Documents';
                UpdatePropagation = Both;
                SubPageLink = "Table ID" = const(Database::"Item Journal Line"),
                              "Template Name" = field("Journal Template Name"),
                              "Batch Name" = field("Journal Batch Name"),
                              "Line No." = field("Line No.");
            }
        }
    }
}

Now, the user can see attached documents for each journal line directly from the Item Journal.

Step 4: Create a Codeunit to Handle the Events

The last step is to hook into the Document Attachment events so that attachments are properly linked to Item Journal Lines.

We subscribe to three main events:

  • OnBeforeDrillDown (opens the record reference),

  • OnAfterOpenForRecRef (applies filters for the attachment list),

  • OnAfterInitFieldsFromRecRef (initializes fields when creating a new attachment).

codeunit 50501 DocumentAttachment
{
    [EventSubscriber(ObjectType::Page, Page::"Document Attachment Factbox",
                                     'OnBeforeDrillDown', '', false, false)]
    local procedure OnBeforeDrillDown(DocumentAttachment: Record "Document Attachment";
                                                                var RecRef: RecordRef);
    var
        ItemJournalLine: Record "Item Journal Line";
    begin
        case DocumentAttachment."Table ID" of
            DATABASE::"Item Journal Line":
                begin
                    RecRef.Open(DATABASE::"Item Journal Line");
                    ItemJournalLine.Reset();
                    if DocumentAttachment."Template Name" <> '' then
                        ItemJournalLine.SetRange("Journal Template Name", DocumentAttachment."Template Name");

                    if DocumentAttachment."Batch Name" <> '' then
                        ItemJournalLine.SetRange("Journal Batch Name", DocumentAttachment."Batch Name");

                    ItemJournalLine.SetRange("Line No.", DocumentAttachment."Line No.");
                    if DocumentAttachment."No." <> '' then
                        ItemJournalLine.SetRange("Document No.", DocumentAttachment."No.");
                    if ItemJournalLine.FindFirst() then;
                    RecRef.GetTable(ItemJournalLine);
                end;
        end;
    end;

    [EventSubscriber(ObjectType::Page, Page::"Document Attachment Details",
                                    'OnAfterOpenForRecRef', '', false, false)]
    local procedure OnAfterOpenForRecRef(var DocumentAttachment: Record "Document Attachment";
                                                                var RecRef: RecordRef);
    var
        FieldRef: FieldRef;
        TemplateName: Code[20];
        BatchName: Code[20];
        Lineno: Integer;

    begin
        case RecRef.Number of
            DATABASE::"Item Journal Line":
                begin
                    FieldRef := RecRef.Field(1);
                    TemplateName := FieldRef.Value;
                    DocumentAttachment.SetRange("Template Name", TemplateName);

                    FieldRef := RecRef.Field(2);
                    Lineno := FieldRef.Value;
                    DocumentAttachment.SetRange("Line No.", Lineno);

                    FieldRef := RecRef.Field(41);
                    BatchName := FieldRef.Value;
                    DocumentAttachment.SetRange("Batch Name", BatchName);
                end;
        end;
    end;

    [EventSubscriber(ObjectType::Table, Database::"Document Attachment",
                         'OnAfterInitFieldsFromRecRef', '', false, false)]
    local procedure OnAfterInitFieldsFromRecRef(var DocumentAttachment:
                     Record "Document Attachment"; var RecRef: RecordRef)
    var
        FieldRef: FieldRef;
        RecNo: Code[20];
        TemplateName: Code[20];
        BatchName: Code[20];
        LineNo: Integer;
    begin
        case RecRef.Number of
            DATABASE::"Item Journal Line":
                begin
                    TemplateName := GetFieldValueAsText(RecRef, 1);
                    DocumentAttachment.Validate("Template Name", TemplateName);

                    FieldRef := RecRef.Field(2);
                    Lineno := FieldRef.Value;
                    DocumentAttachment.Validate("Line No.", Lineno);

                    BatchName := GetFieldValueAsText(RecRef, 41);
                    DocumentAttachment.Validate("Batch Name", BatchName);

                    RecNo := GetFieldValueAsText(RecRef, 7);
                    DocumentAttachment.Validate("No.", RecNo);

                    DocumentAttachment.Validate("Document Type", DocumentAttachment."Document Type"::"Item Journal");
                end;
        end;
    end;

    local procedure GetFieldValueAsText(var R: RecordRef; FieldNumber: Integer): Text[250]
    var
        FieldRef: FieldRef;
    begin
        FieldRef := R.Field(FieldNumber);
        exit(Format(FieldRef.Value));
    end;
}

With this extension in place:

  • Users can attach documents directly to Item Journal Lines,

  • The attachments are visible in a FactBox on the Item Journal,

  • The system automatically links attachments using Template Name, Batch Name, and Line No.,

  • The standard Document Attachment framework is extended in a clean, upgrade-safe way.







This approach can be applied to other journal or document tables too — just extend the Document Attachment table with the necessary keys and subscribe to the same events.

Thank you for your time,
Dharmendra Chavda


Comments

Post a Comment

Popular posts from this blog

Run a Dynamics 365 Plugin from JavaScript on Button Click

-
Image
Trigger a Dynamics 365 Plugin from JavaScript on Button Click In Dynamics 365, plugins usually run when system events happen — like creating, updating, or deleting a record. But in some cases, you might want to run a plugin only when the user clicks a button on a form. This blog will guide you step by step on how to trigger a Dynamics 365 plugin from JavaScript using a Custom Action and a Plugin. Steps to call a plugin from JavaScript   Create a Custom Action Open Advanced Settings → Solutions (or open the specific solution where you want to add the action). Click New in the top menu. Choose Automation → Process. From the process types, pick Action — use an Action when you want to call plugins or custom logic from JavaScript, workflows, or Power Automate. Once you click on Action a Quick Create Process form will open and fill details. After that below form is open and you can update process argument as below. And Activate process. 2. Register the Plugin on the Acti...
Read more

Data Upload into CRM from Excel Using Power Automate

-
Image
When managing a CRM like Microsoft Dynamics 365, uploading data from an Excel file can be a tedious manual task, especially when working with large datasets. You can automate this process using Power Automate (formerly known as Microsoft Flow), saving time and ensuring data consistency. Step 1: Prepare Your Data in Excel Ensure that your Excel file is well-organized, the  first row contains the Header names, and check incorrect values to prevent upload issues. Step 2: Create a table in Excel or based on the requirement.            Import Contact Template Step 3: Upload Your Excel File to OneDrive. Power Automate needs access to your Excel file. Store your file in a cloud-based location like OneDrive for Business or SharePoint: Upload the file to your OneDrive. Take note of the file path, as you will need it in Power Automate. Step 4: Set Up Power Automate to Upload Excel Data to CRM Now, we will set up a flow to automate the data upload process. Log in...
Read more

Add Java Script and CSS in PowerApps Portal

-
Image
Hi Readers, In PowerApps Portals, you can use JavaScript and CSS to customize the appearance and behavior of your portal, including blog content. Here's a general guide on how you can add JavaScript and CSS to a PowerApps Portal for a blog: Open the Powerapps Portal and go to the particular form to Add Javascript and CSS. Copy " owner-operator-compare-survey " to this text form link as mentioned below. Open portal Management form PowerApps and jump to "Web Pages" as below. After that click on the "Partial URL" field and select Filter by option. Paste "owner-operator-compare-survey" into the blank box below and click  "Apply" . Once it's filtered we can see only one record on the web page. Open Record and Click on the "Advance" option.   Add Custom Javascript and Custom CSS based on requirements. Navigate to the " owner-operator-compare-survey" page on your portal and check that javascript and CSS are working...
Read more